$ !
$ ! File name:	    TCPIP$PROXY_RELOAD.COM
$ ! Product:        Compaq TCP/IP Services for OpenVMS
$ ! Version:        V5.1-00
$ !
$ ! Copyright 2001 Compaq Computer Corporation
$ !
$ ! COMPAQ Registered in U.S. Patent and Trademark Office.
$ !
$ ! Confidential computer software.  Valid license from  Compaq
$ ! or  authorized sublicensor required for possession, use  or
$ ! copying.  Consistent with FAR 12.211 and 12.212, Commercial
$ ! Computer Software,   Computer Software Documentation,   and
$ ! Technical Data for Commercial Items  are  licensed  to  the
$ ! U.S. Government under vendor's standard commercial license.
$ !
$     gosub set_dclcmds
$     set noon
$     proxy_status = 1
$     on control_y then goto exit
$     set symbol /scope=(nolocal,global)
$     proxy_privs  = f$edit("cmkrnl,oper,sysnam,sysprv","upcase")
$ !
$ ! set privileges needed to reload proxy
$ !
$ set_privileges:
$     prev_privs = f$setprv(proxy_privs)
$     if .not. f$privilege(proxy_privs)
$     then
$	  write sys$output "TCPIP-E-NOPRIV, requires ''proxy_privs' privileges"
$	  goto error_exit
$     endif
$ !
$ ! check if proxy and NFS have been started; shut down NFS server if so
$ !
$ check_startup:
$     if f$trnlnm("tcpip$proxy_started","tcpip$startup_table",,"executive") .eqs. ""
$     then
$	  write sys$output "%TCPIP-W-NOSERVSTART, Proxy execlet not started"
$     endif
$
$     if f$trnlnm("tcpip$nfs_started","tcpip$startup_table",,"executive") .eqs. ""
$     then
$	  write sys$output "%TCPIP-W-NOSERVSTART, NFS server not started"
$     else
$	  @sys$startup:tcpip$nfs_shutdown.com quiet
$     endif
$ !
$ ! Unload and reload the proxy execlet, then repopulate its proxy database
$ ! and restart the NFS server.
$ !
$ load_proxy:
$     define /system/executive_mode/nolog -
	  tcpip$proxy_services -
	  sys$loadable_images:tcpip$proxy_services.exe
$
$     sysconfig := $sys$system:tcpip$sysconfig.exe
$     sysconfig -u proxy
$
$     sysconfig -c proxy
$     tcpip load proxy
$     if $status
$     then
$	  write sys$output "%TCPIP-I-INFO, NFS server proxies reloaded"
$     endif
$
$     @sys$startup:tcpip$nfs_startup.com 'p1'
$
$ !
$ ! restore previous privileges and exit
$ !
$ exit:
$     if f$type(prev_privs) .nes. ""
$     then
$	  prev_privs = f$setprv(prev_privs)
$     endif
$
$     exit proxy_status
$ !
$ ! proxy reload error
$ !
$ error_exit:
$     proxy_status = %x10000002
$     write sys$output "%TCPIP-E-RELOFAIL, failed to reload NFS proxy database"
$     goto exit
$ !
$ ! insure dcl commands aren't redefined by user
$ !
$ set_dclcmds:
$     define   := define
$     exit     := exit
$     return   := return
$     set      := set
$     write    := write
$     return