$ GOTO BEGIN
$!-----------------------------------------------------------------------------
$!+ 
$!  TCPIP$EXTENSION_MIB_STARTUP.COM 
$!  V5.1-00 
$! 
$! Copyright 1998 Compaq Computer Corporation 
$! 
$! COMPAQ Registered in U.S. Patent and Trademark Office. 
$! 
$! Confidential computer software. Valid license from Compaq or 
$! authorized sublicensor required for possession, use or copying. 
$! Consistent with FAR 12.211 and 12.212, Commercial Computer Software, 
$! Computer Software Documentation, and Technical Data for Commercial 
$! Items are licensed to the U.S. Government under vendor's standard 
$! commercial license. 
$! 
$!+ 
$! Command procedure to install images for extension subagents.  
$! Assumption is that this procedure is called from TCPIP$SNMP_STARTUP.COM 
$! and required privileges are already enabled by the caller. 
$! 
$! 28-jul-1998  Sheldon Bishov  sdb-v5.0-00 
$!      - Initial version, adapted from TCPIP$SNMP_STARTUP.COM 
$!
$! 10-aug-1999  Sheldon Bishov V5.1-00 
$!      - Add check for missing images.
$!      - Neaten up with gosub and explicit error message. 
$! 
$! 07-mar-2000  Sheldon Bishov  V5.1-00 
$!      Update with current example (Chess).
$!
$!-----------------------------------------------------------------------------
$! 
$BEGIN: 
$! 
$ ON CONTROL_Y THEN GOTO EXIT 
$! 
$ ON WARNING THEN GOTO NO_SHARED
$! 
$ GOTO EXIT 
$! 
$! If planning to run the Chess example copy TCPIP$CHESS_SUBAGENT.EXE
$! from TCPIP$SNMP_EXAMPLES, or from location where built, to SYS$SYSTEM.
$!
$! In addition, use the following instructions if images need to be installed,
$! with or without privileges:
$! - Specify any required privileges as IMAGE_PRIVS; if more than one privilege
$!   is required, use a comma separated list.
$! - Remove or comment out the GOTO above. 
$! - Edit the next two lines and replicate all three lines as needed. 
$ LIBRARY = "SYS$SYSTEM:TCPIP$CHESS_SUBAGENT.EXE"
$ IMAGE_PRIVS = ""
$ GOSUB INSTALL_IMAGE
$!
$EXIT:
$ EXIT
$!
$NO_SHARED:
$ WRITE SYS$OUTPUT "Failed to install image(s)"
$ WRITE SYS$OUTPUT "TCPIP subagent requires ''LIBRARY'"
$ GOTO EXIT
$!
$INSTALL_IMAGE:  ! V5.1-00
$ IF F$SEARCH (LIBRARY) .EQS. "" 
$ THEN
$   WRITE SYS$OUTPUT "-TCPIP-E-SNMPCONF, image ''LIBRARY' missing."
$ ELSE IF .NOT. F$FILE (LIBRARY,"KNOWN") 
$   THEN
$     IF IMAGE_PRIVS .EQS. "" 
$     THEN
$	INSTALL CREATE 'LIBRARY'/HEADER/SHARE
$     ELSE
$	INSTALL CREATE 'LIBRARY'/HEADER/SHARE/PRIVILEGED=('IMAGE_PRIVS')
$     ENDIF
$   ENDIF
$ ENDIF
$ RETURN