1 disable
Many entities have a status attribute called state, whose value
reflects the current operational state of the entity. The value
of state is usually either:
off The entity is disabled. In this state the entity exists and
can be manipulated in various ways (for example, by having
its characteristics modified), but will not perform its
primary functions.
on The entity is enabled. In this state the entity is fully
operational.
Use the disable command to place the entity in its disabled
(off) state. Many entities do not permit you to modify their
characteristics while they are enabled, so you must use the
disable command before using the add, remove, or set commands.
Also, it is often the case that you cannot delete an entity while
it is enabled, so you must use the disable command before using
the delete command. For example,
ncl> disable modem connect line line-1
disables the entity to suspend its operation temporarily and
suspends operation of the corresponding physical line.
2 alias_(OpenVMS)
3 port
disable [node node-id] alias port port-name
2 csma-cd
3 station
disable [node node-id] csma-cd station station-name
Example:
disable csma station csmacd-1
2 ddcmp_(OpenVMS_VAX)
3 link
disable [node node-id] ddcmp link link-name
Example:
disable ddcmp link ddcmp-0
4 logical_station
disable [node node-id] ddcmp link link-name -
logical station station-name
Example:
disable ddcmp link ddcmp-0 logical station ddcmp-0
2 dtss
disable [node node-id] dtss
2 event_dispatcher
disable [node node-id] event dispatcher
3 outbound_stream
Disables an event dispatcher outbound stream entity which
represents an outgoing connection to a sink on a local or
remote node.
disable [node node-id] event dispatcher -
outbound stream simple-name [method disable-method]
The optional Method argument specifies whether an existing
connection should be aborted immediately or shut down in an
orderly fashion. The disable methods are:
abort The stream calls the disconnect operation to abort
the connection immediately.
orderly The stream calls the shutdown operation to perform an
orderly shutdown of the connection. This is the
default method.
Examples:
disable event dispatcher outbound stream local_stream
disable event dispatcher -
outbound stream local_stream method abort
4 Exception_Messages
o incomplete
Orderly disable could not be completed due to lack of transport
confidence.
3 relay
disable [node node-id] event dispatcher relay
4 logging
Transitions the state of the specified logging entity
to off.
disable [node node-id] event dispatcher -
relay logging logging-type
Examples:
disable event dispatcher relay logging console
disable event dispatcher relay logging monitor
disable event dispatcher relay logging file
3 sink
disable [node node-id] event dispatcher sink simple-name
Example:
disable event dispatcher sink local_sink
2 fddi
3 station
disable [node node-id] fddi station station-name
Example:
disable fddi station fddi-1
4 link
disable [node node-id] fddi station station-name -
link link-index
OpenVMS Example:
disable fddi station fddi-0 link 0
Tru64 UNIX Example:
disable fddi station fddi-1 link 1
5 Exception_Messages
o invalid item list format (OpenVMS)
Confirm that latest LAN driver patch kit from OpenVMS
has been installed.
o return data corrupt or incorrectly encoded on
remote system (OpenVMS)
Confirm that latest LAN driver patch kit from OpenVMS
has been installed on both the local and remote systems.
4 phy_port
disable [node node-id] fddi station station-name -
phy port port-index
OpenVMS Example:
disable fddi station fddi-0 phy port 0
Tru64 UNIX Example:
disable fddi station fddi-1 phy port 1
5 Exception_Messages
o invalid item list format (OpenVMS)
Confirm that latest LAN driver patch kit from OpenVMS
has been installed.
o return data corrupt or incorrectly encoded on
remote system (OpenVMS)
Confirm that latest LAN driver patch kit from OpenVMS
has been installed on both the local and remote systems.
2 frame_(OpenVMS)
disable [node node-id] frame
3 link
disable [node node-id] frame link frame-link-id
Example:
disable frame link frame-0
2 hdlc
3 link
disable [node node-id] hdlc link link-name
Example:
disable hdlc link hdlc-0
4 logical_station
disable [node node-id] hdlc link link-name -
logical station logical-station-name
Example:
disable hdlc link hdlc-0 logical station hdlc-0
2 lapb
3 link
disable [node node-id] lapb link simple-name
Example:
disable lapb link link-0
2 llc2
3 sap
disable [node node-id] llc2 sap simple-name
Example:
disable llc2 sap sap-0
4 link
disable [node node-id] llc2 sap simple-name -
link simple-name
Example:
disable llc2 sap sap-0 link dte-1
2 modem_connect
3 line
disable [node node-id] modem connect line line-name
Example:
disable modem connect line DSY-0-0
2 mop
disable [node node-id] mop
3 circuit
Removes a set of MOP service functions from the specified MOP
circuit.
disable [node node-id] mop circuit circuit-name -
functions {function[,function...]}
The Functions argument is required for the disable mop circuit
commands. The MOP Circuit Functions include:
configuration monitor load server
console requester loop requester
dump server query requester
load requester (Tru64 UNIX) test requester
Examples:
disable mop circuit csmacd-1 -
functions {configuration monitor}
disable mop circuit fddi-1 -
functions {dump server, load server}
2 ncl
3 logging
disable ncl logging
This will discontinue the logging of ncl commands to the NCL log
file. This logging was established earlier in the NCL session
with the "set ncl logfile" and "enable ncl logging" commands. To
determine the name of the log file, use the "show ncl logfile"
command.
For example, on OpenVMS:
NCL>set ncl logfile test
NCL>enable ncl logging
NCL>show all
NCL>disable ncl logging
NCL>show ncl logfile
Logfile name is: test
Logfile is Disabled
The results will be in the file TEST.NCL. That file will contain
the logged NCL command(s), and the output will be commented out.
You may then reissue the command(s) you logged by:
NCL>do test.ncl
3 uid_display_(Tru64_UNIX)
By default, unique identification (UID) values are not displayed in
NCL output. Use the enable ncl uid display command if you wish to
see this attribute displayed. Use the following command to turn
UID displays back off:
disable ncl uid display
For more information, refer to HELP NCL OUTPUT DISPLAYING_UIDS.
2 function
disable [node node-id] function function-arg
Example:
disable function address watcher
Disables node entity functions as specified by the function-arg.
Possible function-arg values are:
address Disabling this function causes the state attribute
watcher to be set to off, but the node can still respond to
management through its CMIP interface. The disable
function is only supported on OpenVMS.
CMIP Enabled automatically by the software. This
listener function permits the node to respond to management
through its CMIP listener interface. The CMIP
listener function is only supported on OSF/1.
2 nsp
disable [node node-id] nsp
2 osak
Puts the OSAK entity in the NotAvailable state in which it does not
accept any more inbound or outbound association requests, and
existing associations are aborted. If the OSAK entity is already in
the NotAvailable state, the command has no effect.
disable [node node-id] osak
2 osi_transport
disable [node node-id] osi transport
2 routing
disable [node node-id] routing
3 circuit
disable [node node-id] routing circuit circuit-name
Example:
disable routing circuit csmacd-1
4 ip_reachable_address
disable [node node-id] routing circuit circuit-name -
ip reachable address simple-name
4 reachable_address
disable [node node-id] routing circuit circuit-name -
reachable address simple-name
Example:
disable routing circuit csmacd-1 reachable address to-bulean
3 egp_group
disable [node node-id] routing egp group group-name
4 egp_neighbor
disable [node node-id] routing egp group group-name -
egp neighbor neighbor-name
2 session_control
disable [node node-id] session control
2 token_ring_(Tru64_UNIX)
disable [node node-id] token ring station station-name
2 x25_access
disable [node node-id] x25 access
3 application
disable [node node-id] x25 access -
application application-name
Example:
disable x25 access application X25_MAIL
2 x25_client_(OpenVMS)
disable [node node-id] x25 client
2 x25_protocol
disable [node node-id] x25 protocol dte dte-name
Example:
disable x25 protocol dte dte-1
2 x25_relay_(Alpha)
3 client
disable [node node-id] x25 relay client client-name
3 pvc
disable [node node-id] x25 relay pvc pvc-name
2 x25_server
disable [node node-id] x25 server
3 client
disable [node node-id] x25 server client simple-name
2 xot_(OpenVMS_Alpha)
3 sap
disable [node node-id] xot sap sap-name
Disables a Service Access Point (SAP) subentity of the
X.25 Over TCP/IP (XOT) module. The sap-name is a simple
name which uniquely identifies a particular SAP
instance.
Example:
disable xot sap sap-0
4 link
disable [node node-id] xot sap sap-name link link-name
Disables XOT communications with a particular remote system
identified by the LINK's remote IP addres and remote RFC1613
port number. The sap-name and link-name are simple names
which uniquely identify particular SAP and LINK instances.
Example:
show xot sap sap-0 link * remote ip addr
disable xot sap sap-0 link link-0