$! Setup up VIM symbol and logical names
$! Phil Ottewell Jan 2001
$!
$ this_file = F$ENVIRONMENT("PROCEDURE")
$ file_dir = F$PARSE(this_file,,,"DIRECTORY")
$ file_dev = F$PARSE(this_file,,,"DEVICE")
$ this_dir = file_dev + file_dir
$ vim_help_dir = this_dir - "]" + ".DOC]"
$!
$! You may wish to define the following logicals
$ DEFINE/JOB/NOLOG TERM "ansi"
$ DEFINE/JOB/NOLOG TMP SYS$SCRATCH:
$ DEFINE/JOB/NOLOG VIM 'this_dir'
$ DEFINE/JOB/NOLOG VIMRUNTIME 'this_dir'
$ DEFINE/JOB/NOLOG VIM_HLP 'vim_help_dir'
$!
$ is_alpha = F$EXTRACT(0,4,F$GETSY("NODE_HWTYPE")).EQS."ALPH"
$! Get correct EXEs - allows Alpha and VAX exes to coexist
$! assuming that they are VIM.EXE_ALPHA and VIM.EXE respectively
$ IF is_alpha
$ THEN
$   exe = "EXE_ALPHA"
$ ELSE
$   exe = "EXE"
$ ENDIF
$!
$ VI*M:==$'this_dir'VIM.'exe'
$ IF F$TYPE(LOGIN).NES.""
$ THEN
$   WRITE SYS$OUTPUT "Warning - you have a symbol called LOGIN set."
$   WRITE SYS$OUTPUT "This will interfere with the correct operation of VIM"
$   WRITE SYS$OUTPUT "Try DELETE/SYMBOL/GLOBAL LOGIN or DELETE/SYMBOL LOGIN"
$   WRITE SYS$OUTPUT "if you see and error message about trying to write"
$   WRITE SYS$OUTPUT "the .viminfo file"
$ ENDIF
$!
$ EXIT